Sakelar Elektronik & Driver Motor

Pin digital Arduino dirancang untuk mengirimkan sinyal data, bukan tenaga (power). Sebuah pin digital pada Arduino Uno maksimum hanya mampu menyuplai arus sekitar 20-40 mA pada tegangan 5V.

Sebagai perbandingan:

• LED biasa: butuh 15 mA (Aman!)
• Motor DC kecil: butuh 300 mA - 1000 mA (Bahaya!)
• Pompa Air Mini: butuh 500 mA - 2000 mA (Bahaya!)

Untuk mengontrol beban besar, Arduino membutuhkan "tangan bantuan". Salah satunya adalah Relay. Relay adalah sakelar mekanik yang digerakkan oleh elektromagnet.

Selain relay, kita juga bisa menggunakan Transistor (seperti TIP120, MOSFET) sebagai sakelar elektronik. Berbeda dengan relay yang menggunakan gerakan mekanik dan bersuara "cetek-cetek", transistor murni elektronik sehingga sunyi dan bisa hidup-mati ribuan kali per detik.

Jika kita ingin membuat mobil robot, kita tidak hanya ingin motor berputar atau mati, tapi juga ingin motor bisa maju, mundur, dan diatur kecepatannya. Transistor tunggal hanya bisa mengatur satu arah. Untuk itu, kita menggunakan komponen H-Bridge seperti Modul L298N.

L298N memungkinkan kita mengatur 2 motor DC sekaligus (Motor A dan Motor B). Modul ini bekerja sebagai jembatan: menyalurkan tenaga dari Baterai besar menuju Motor, sementara Arduino cukup "memberikan perintah".

Pada Driver L298N, untuk satu motor (misal Motor A) terdapat 3 pin kontrol:

• IN1 & IN2: Menentukan arah putaran (maju/mundur)
• ENA (Enable A): Menentukan kecepatan dengan sinyal PWM (0 - 255)

// L298N Motor Driver
#define IN1 8
#define IN2 9
#define ENA 10  // PWM speed control

void setup() {
  pinMode(IN1, OUTPUT);
  pinMode(IN2, OUTPUT);
  pinMode(ENA, OUTPUT);
  Serial.begin(9600);
  Serial.println("Motor Driver L298N siap!");
}

void putarMaju(int kecepatan) {
  digitalWrite(IN1, HIGH);
  digitalWrite(IN2, LOW);
  analogWrite(ENA, kecepatan); // kecepatan: 0-255
  Serial.print("Maju - Kecepatan: "); Serial.println(kecepatan);
}

void putarMundur(int kecepatan) {
  digitalWrite(IN1, LOW);
  digitalWrite(IN2, HIGH);
  analogWrite(ENA, kecepatan);
  Serial.print("Mundur - Kecepatan: "); Serial.println(kecepatan);
}

void berhenti() {
  digitalWrite(IN1, LOW);
  digitalWrite(IN2, LOW);
  analogWrite(ENA, 0);
  Serial.println("BERHENTI");
}

void loop() {
  putarMaju(150);   // Kecepatan sedang
  delay(2000);
  berhenti();       // Jeda sejenak sebelum berbalik arah
  delay(500);
  putarMundur(200); // Kecepatan agak cepat
  delay(2000);
  berhenti();
  delay(500);
}